如何在 Windows 10 中備份和還原資料夾視圖設置

在 Windows 中，您可以按照您想要的方式變更範本檢視、列寬、分組依據、排序依據以及資料夾內容的版面配置。

本教學將向您展示如何備份和還原Windows 10中任何帳戶的資料夾視圖設定、詳細資訊、預覽面板寬度和大小、導覽視窗寬度、開啟和另存為對話方塊。

就是這樣：

1.下載 Backup_and_Restore_Folder_View_Settings_Tool.bat 檔案。

筆記：

此 .bat 檔案將僅套用備份並還原到目前帳戶。

以下是該 .bat 檔案的內容以供參考：

代碼：

@ECHO OFF

Set "+=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
For /F "tokens=* " %%# in ('Reg Query "%+%" /V Desktop') Do (Set "#=%%#")
Set "#=%#:*REG_EXPAND_SZ    =%"
For /F "delims=" %%# in ('Echo "%#%"') Do (Set "#=%%#")
Set "[Desktop]=%#:~1,-1%"


title Backup and Restore Folder View Settings Tool
:choice
cls
echo.
echo OPTIONS:
echo.
echo 1. Back up your folder view settings.
echo 2. Restore folder view settings from backup.
echo 3. Cancel
echo.
echo.
set /P c=Type the option number you would like to do, and press Enter?
if /I "%c%" EQU "1" goto :verify1
if /I "%c%" EQU "2" goto :verify2
if /I "%c%" EQU "3" exit
goto :choice


:verify1
IF EXIST "%[Desktop]%\Folder View Settings Backup" goto :response1
goto :backup

:response1
echo.
echo.
echo You already have a "Folder View Settings Backup" folder on your desktop.
echo Please move it to another location, and try again.
echo.
pause
goto :choice


:backup
mkdir "%[Desktop]%\Folder View Settings Backup"
REG EXPORT "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\Shell\BagMRU" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\Shell\Bags" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\GlobalSettings\Sizer" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_GlobalSettings_Sizer.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\NavPane" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_NavPane.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDOpen" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDOpen.reg" /y 
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDSave" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDSave.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\ComDlg32" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_ComDlg32.reg" /y
cls
echo.
echo Backup of folder view settings successfully completed.
echo.
pause 
exit

:verify2
IF NOT EXIST "%[Desktop]%\Folder View Settings Backup" goto :response
goto :restore

:response
echo.
echo.
echo You do not have a "Folder View Settings Backup" folder on your desktop.
echo Please place the backup folder on your desktop, and try again.
echo.
pause
goto :choice


:restore 
REG Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\GlobalSettings\Sizer" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\NavPane" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDOpen" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDSave" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\ComDlg32" /F

REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_GlobalSettings_Sizer.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_NavPane.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDOpen.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDSave.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_ComDlg32.reg"

cls
echo.
echo Backup of folder view settings successfully restored.
echo.
echo Waiting to restart explorer to apply.
echo Your screen will flash as explorer is restarted.
echo.
echo.
pause
taskkill /f /im explorer.exe
start explorer.exe 
exit

2. 將.bat 檔案儲存到桌面。

3. 解除阻止.bat 檔案。

4. 運行.bat 檔案。

5. 在備份和還原資料夾檢視設定工具中執行您想要執行的動作。

如何備份和恢復開始功能表佈局

備份：

建立資料夾視圖設定的備份時，「資料夾視圖設定備份」資料夾將儲存到桌面，其中包含從資料夾視圖設定的註冊表匯出的.reg 檔案。您可以將此資料夾保存在您想要儲存的位置。

恢復：

當您想要還原資料夾檢視設定的備份時，您首先需要在桌面上有一個具有該確切名稱的資料夾檢視設定備份資料夾才能繼續復原程序。

如何在 Windows 10 中備份和還原資料夾視圖設置

Windows 10 中的備份和還原資料夾視圖設置

希望你成功。

Tags: #資料夾視圖 #資料夾視圖 win 10 #備份資料夾檢視 #還原資料夾視圖

智慧型手機是否附有防毒軟體？

我們使用智慧型手機連接到互聯網並下載軟體和文件，這意味著它們容易受到惡意活動的影響。那麼智慧型手機是否自備防毒軟體，還是需要自行安裝防護程式呢？

只需幾個簡單的步驟即可將您的 PC 變成 WiFi 路由器

如果您使用的是缺乏 WiFi 支援的過時調變解調器，您將無法使用有線連接以外的任何功能。但是，您可以將您的 PC 變成無線路由器，將網路連接到周圍所有支援 WiFi 的裝置。

如何在 Windows 10 上開啟網路喚醒以遠端開啟和啟動電腦

LAN 喚醒 (WOL) 是一項遠端電腦啟動功能。 LAN 喚醒允許電腦「偵聽」包含 MAC 位址的“神奇封包”，以透過 LAN 或 Internet 喚醒電腦。

如何在 Windows 10 中備份和還原資料夾視圖設置

本教學將向您展示如何備份和還原 Windows 10 中任何帳戶的資料夾視圖設定、詳細資訊、預覽面板寬度和大小、導覽視窗寬度、開啟和另存為對話方塊。

如何在 Windows 10 上的電影和電視應用程式中啟用/停用全螢幕播放

預設情況下，視訊播放始終在電影和電視中以全螢幕模式開始。本指南將向您展示如何在 Windows 10 的電影和電視應用程式中啟用或停用全螢幕模式下始終啟動的視訊播放功能。

不要錯過 Windows 10 上可用的有用工具！

Windows 10上的內建工具經常被使用者忽視和關注。但是，如果您了解並能夠利用它，您在電腦上工作時的操作將會更快，並帶來許多其他好處。

刪除可卸載程式的 10 個技巧

一堆不需要的軟體會使您的電腦變得緩慢且混亂。但清理並不總是那麼容易。因此，請查看這 10 種方法來徹底卸載應用程式、批量刪除舊軟體、卸載項目，甚至刪除預先安裝的 Windows 程式。

如何在 Windows 10 上固定 Steam 遊戲功能？

如果您透過 Steam 玩遊戲，您可能會注意到，即使您從 Steam 庫創建了遊戲的快捷方式，也無法固定 Steam 遊戲功能。原因是因為創建的 Steam 快捷方式是連結到網路的快捷方式。

關於 Windows 10 上的 Outlook Express 您需要了解的所有信息

Outlook Express 是整合在 Windows 98 到 Server 2003 的 Windows 版本上的基本電子郵件應用程式。Microsoft 從 Windows Vista 開始正式停止整合 Outlook Express，儘管您仍然可以使用該應用程式執行任務。執行某些任務。

IP位址192.168.2.2使用說明

192.168.2.2 是私人 IP 位址，有時在本地網路上使用。這是從 192.168.2.1 開始的 IP 範圍中的第二個 IP 位址，有時稱為網路 192.168.2.0。